Cara Menghitung Penyusutan Aktiva Tetap dengan 2 Rumus Excel Sederhana

Mengapa nilai penyusutan harus diperhitungkan? Dan bagaimana cara menghitung penyusutan aktiva tetap?

Nilai penyusutan aktiva tetap harus diperhitungkan dengan akurat, karena akan mempengaruhi tingkat akurasi sebuah laporan keuangan baik Neraca maupun Laba Rugi.

Akuntansi penyusutan adalah suatu metode untuk mengalokasikan harga perolehan aktiva tetap ke periode-periode akuntansi.

Dan berikut ini tutorial penggunaan rumus Excel untuk menghitung nilai penyusutan aktiva tetap.

Sederhana, mudah dan langsung bisa diterapkan untuk BISNIS Anda.

Yuks segera dimulai…

 

01: Pengertian Penyusutan/Depresiasi

cara menghitung penyusutan excel

A: Definisi Penyusutan Menurut Para Ahli

Penyusutan atau depresiasi adalah istilah yang digunakan untuk menunjukkan alokasi harga perolehan aktiva tetap berwujud yang dapat diganti seperti gedung, mesin dan peralatan.

Ada 3 faktor yang memengaruhi besarnya beban depresiasi yang akan dialokasikan pada tiap periode akuntansi, yaitu:

1. Harga perolehan (Aquisition Cost)

Harga perolehan adalah harga beli aset ditambah dengan biaya-biaya yang dikeluarkan sejak proses pembelian sampai dengan aset tersebut siap digunakan.

 

2. Nilai Sisa (Salvage Value)

Nilai sisa adalah taksiran nilai uang yang akan diterima bila aset tersebut dijual setelah masa manfaatnya berakhir.

 

3. Umur Ekonomis (Economical Life Time)

Umur ekonomis adalah perkiraan jangka waktu pemakaian aset.

Taksiran umur ekonomi ini bisa dinyatakan dalam periode waktu, jumlah hari produksi dan total jam kerja.

 

B: Metode Penyusutan

Setelah ketiga faktor itu diketahui, maka selanjutnya adalah menghitung nilai penyusutan.

Ada beberapa metode atau cara menghitung penyusutan, antara lain:

  1. Metode Penyusutan Garis Lurus (straight line method)
  2. Metode Penyusutan Saldo Menurun (declining balanced method)

Dan dalam kesempatan ini saya akan membahas 2 (dua) metode perhitungan nilai penyusutan, yaitu metode garis lurus (Straight Line Method) dan Metode Saldo Menurun (Declining Balanced Method).

Yuk kita kaji satu per satu …

 

02: Metode Garis Lurus (Straight Line Method)

Penyusutan Metode Garis Lurus

A: Pengertian Metode Garis Lurus

Cara menghitung penyusutan dengan metode garis lurus adalah cara menghitung nilai penyusutan aktiva tetap di mana nilai aset tetap memiliki kontribusi yang sama selama masa ekonomisnya.

Sehingga alokasi nilai penyusutannya pun sama dari waktu ke waktu.

 

B: Cara Menghitung Penyusutan Metode Garis Lurus

Bagaimana langkah-langkah cara menghitung penyusutan nya?

Cara menghitung penyusutan aktiva tetap menggunakan metode ini adalah :

(Harga Perolehan – Nilai Sisa) : Umur Ekonomis

Dan Microsoft Excel juga menyediakan fungsi yang dapat digunakan untuk menghitung nilai penyusutan aset tetap dengan metode garis lurus.

Fungsi Excel yang digunakan untuk menghitung penyusutan dengan metode ini adalah SLN.

Penulisan rumusnya adalah sebagai berikut :

=SLN(cost;salvage;life)

Keterangan :

Cost       : Harga Perolehan Aset
Salvage : Nilai Sisa
Life        : Umur Ekonomis

 

C: Contoh Soal Penyusutan Garis Lurus dan Jawabannya

cara menghitung penyusutan peralatan

Perhatikan contoh sola cara menghitung penyusutan aktiva tetap berikut ini :

PT MK Network membeli mesin penggorengan teri krispi senilai Rp 100.000.000,-.

Taksiran nilai sisa aset atau nilai residu adalah sebesar Rp 10.000.000.

Umur ekonomis 10 tahun.

Berapa nilai penyusutan per bulan dan per tahunnya?

Pembahasan jawaban:

#1: Nilai penyusutan per tahun:

Dari data-data di atas, maka cara menghitung penyusutan per tahunnya adalah :

=SLN(100000000;10000000;10)
= Rp. 9.000.000

#2: Nilai penyusutan per bulan:

Dan per bulannya adalah Rp. 9.000.000 : 12 = Rp. 750.000

 

03: Metode Saldo Menurun (Declining Balanced Method)

Penyusutan Metode Saldo Menurun

A: Pengertian Metode Saldo Menurun

Cara menghitung penyusutan dengan metode saldo menurun beranggapan bahwa aset tetap akan memberikan kontribusi yang nilainya besar di awal periode pemakaian.

Kontribusi aset tetap tersebut selanjutnya akan terus menurun sampai akhir masa ekonomisnya.

 

B: Cara Menghitung Penyusutan Metode Saldo Menurun

Bagaimana cara menghitung nilai penyusutan aktiva tetap dengan metode saldo menurun?

Untuk menghitung nilai penyusutan, kita bisa menggunakan fungsi yang disediakan oleh Microsoft Excel.

Fungsi rumus Excel yang digunakan untuk menghitung nilai penyusutan dengan metode ini adalah DB (Declining Balance).

Dan  untuk penulisan rumusnya adalah sebagai berikut :

=DB(cost;salvage;life;periode;[month])

Keterangan:

Cost       : Harga Perolehan Aset Tetap
Salvage : Nilai Sisa
Life        : Umur Ekonomis
Periode : Penurunan tahun ke-
Month  : (optional) Jumlah bulan pertahun, bisa diabaikan dengan asumsi jumlah 12 bulan.

 

C: Contoh Soal Penyusutan Saldo Menurun dan jawabannya

Perhatikan contoh soal cara menghitung penyusutan aktiva tetap menggunakan metode saldo menurun berikut ini:

MyCom Computer Course membeli komputer untuk server mini senilai Rp  25 juta.

Komputer itu akan dipakai selama 5 tahun.

Nilai komputer setelah 5 tahun diperkirakan Rp. 500.000.

Berapa nilai penyusutan komputer tersebut tahun ke-4?

Pembahasan jawaban:

Nilai penyusutan komputer di tahun ke-4 adalah sebagai berikut :

=DB(25000000;500000;5;4)
= Rp. 1.295.652

 

04: Cara Menghitung Penyusutan dengan Sistem Aplikasi Excel

cara menghitung penyusutan kendaraan

A: Bentuk Aplikasi Excel Sederhana untuk Menghitung Penyusutan

Untuk membandingkan dua metode tersebut dan untuk memudahkan perhitungan nilai penyusutan sehingga bisa digunakan sebagai template.

Maka kita bisa membuat tabel penyusutan excel seperti berikut ini:

Tabel Perhitungan penyusutan aktiva tetap Excel
Gambar. aplikasi penyusutan aktiva tetap Excel

Keterangan tabel :

Untuk mengetahui nilai penyusutan aset tetap tertentu, kita bisa memilih daftar nama aset dan metode penyusutan yang dikehendaki.

Selanjutnya kolom yang lain, yaitu tanggal perolehan, harga perolehan, awal periode penyusutan, taksiran masa manfaat,

Taksiran Nilai Sisa, Akhir Periode Penyusutan,dan Nilai Penyusutan Aktiva secara otomatis data-data yang lain akan  ditampilkan.

 

B: Langkah-langkah Membuat Aplikasi Excel untuk Menghitung Penyusutan

cara menghitung penyusutan fiskal

Langkah-langkah membuat aplikasi Excel untuk menghitung nilai penyusutan aktiva tetap:

A. Langkah  Aplikasi Penyusutan Excel #1:

Buat sheet dan berilah nama ASET TETAP. Tabel ini berisi daftar aset tetap yang dimiliki.

Bentuknya seperti ini :

cara menghitung penyusutan aset
Daftar Aktiva Tetap dengan Nilai penyusutannya

 

B. Langkah Aplikasi Penyusutan Excel #2:

Buat sheet kedua dan berilah nama PENYUSUTAN. Bentuk tabelnya seperti gambar tabel 1 di atas.

 

C. Langkah Membuat Aplikasi Penyusutan Excel #3:

Masukkan rumus excel ke kolom-kolom berikut ini :

01. Nama Aset :

Buat list nama aset tetap dengan menggunakan fungsi Data Validation.

Caranya klik Data – Data Validation. Maka akan muncul form dan isi seperti gambar berikut ini :

Aplikasi Penyusutan Excel
Aplikasi Penyusutan Excel

 

02. Kelompok Akun :

Masukkan rumus excel berikut ini :

=IF(ISBLANK(E10);” “;INDEX(‘Aset Tetap’!D10:D14;MATCH(E10;’Aset Tetap’!C10:C14;0)))

Keterangan rumus :

Jika sel Nama Akun bernilai kosong maka hasilnya kosong.

Jika tidak maka ambil data kelompok akun dari tabel aset tetap sesuai dengan nama aset yang dipilih di sel Nama Akun.

 

03. Tanggal Perolehan :

Untuk mengambil data tanggal perolehan aset dari tabel aset tetap, masukkan rumus excel berikut ini:

=IF(ISBLANK(E10);” “;INDEX(‘Aset Tetap’!E10:E14;MATCH(E10;’Aset Tetap’!C10:C14;0)))

 

04. Harga Perolehan :

Untuk mengambil data harga perolehan dari tabel aset tetap, masukan rumus excel seperti ini :

=IF(ISBLANK(E10);” “;INDEX(‘Aset Tetap’!F10:F14;MATCH(E10;’Aset Tetap’!C10:C14;0)))

 

05. Awal Periode Penyusutan :

Masukkan rumus excel seperti berikut ini :

=IF(ISBLANK(E10);” “;EOMONTH(C14;0))

Keterangan rumus :

Jika sel nama aset bernilai kosong maka hasilnya kosong.

Jika tidak maka fungsi EOMONTH akan menampilkan tanggal terakhirdari data bulan yang ada di sel Tanggal Perolehan.

 

 06. Taksiran Masa Manfaat :

Untuk mengambil data taksiran masa manfa’at, masukkan rumus excel berikut ini :

=IF(ISBLANK(E10);” “;INDEX(‘Aset Tetap’!G10:G14;MATCH(E10;’Aset Tetap’!C10:C14;0)))

 

07. Taksiran Nilai Sisa:

Untuk mengambil data taksiran sisa, masukkan rumus excel berikut ini :

=IF(ISBLANK(E10);” “;INDEX(‘Aset Tetap’!H10:H14;MATCH(E10;’Aset Tetap’!C10:C14;0)))

 

08. Akhir Periode Penyusutan:

Masukkan rumus excel berikut ini :

=IF(ISBLANK(E10);” “;EDATE(C18;(F14*12)-1))

Keterangan rumus :

Jika sel Nama Akun bernilai kosong maka hasilnya kosong.

Jika tidak maka fungsi EDATE akan menampilkan data tanggal terakhir periode penyusutan yaitu tanggal awal periode ditambah jumlah periode penyusutan.

 

09. Metode Penyusutan:

Buat daftar metode penyusutan yang diinginkan dengan menggunakan fungsi Data Validation seperti langkah pertama.

Isikan data-data seperti dibawah ini :

cara menghitung penyusutan aset
Aplikasi Penyusutan Excel

 

Bila sampai tahapan ini dengan benar, maka ketika Anda memilih nama aset dan metode penyusutan tertentu maka data-data lain akan mengikutinya.

Contohnya Anda memilih nama aset MOTOR dan metode penyusutan GARIS LURUS, maka data-data lain akan mengikutinya.

cara menghitung penyusutan komersial
Aplikasi Penyusutan Excel

 

D. Langkah  Aplikasi Penyusutan Excel #4: Beralih ke tabel nilai penyusutan aktiva

Perhatikan langkah ke-empat berikut ini:

01. Kolom Tahun :

Baris #1. Masukkan rumus excel berikut ini :

=IF(ISBLANK($E$10);” “;YEAR(C18))

Keterangan rumus :

Jika sel Nama Aset bernilai kosong maka hasilnya kosong, jika tidak maka ambil data tahun dari sel Awal Periode Penyusutan.

Baris #2. Masukkan rumus excel beriku ini :

=IF(ISBLANK($E$10);” “;IF(B25<$B$25+$F$14;B25+1;” “))

Keterangan rumus :

Jika sel nama aset bernilai kosong maka hasilnya kosong.

Jika nilai sel baris #1 kolom TAHUN lebih kecil dari hasil penjumlahan sel baris #1 ditambah sel di Taksiran Masa Manfaat, maka tambahkan nilai sel baris #1 dengan 1 (satu).

Selain itu hasilnya kosong.

Salin rumus Baris #2 di kolom Tahun sampai baris terakhir dari Tabel.

 

02. Kolom Jumlah Bulan :

Masukkan rumus excel berikut ini :

=IF(OR($E$10=0;B25=” “);” “;IF(B25=YEAR($C$18);12 MONTH($C$18)+1;IF(B25<YEAR($F$18);”12”;IF(B25=YEAR($F$18);MONTH($F$18)))))

Penjelasan rumus:

Arti dari rumus excel di atas adalah Jika sel nama aset bernilai kosong maka hasilnya kosong.

Bila tahun pada sel B25 (baris#1 kolom Tahun) sama dengan tahun pada sel C18 (awal periode penyusutan) maka 12 dikurangi jumlah bulan pada sel C18 lalu ditambah 1.

Jika tahun pada sel B25 lebih kecil dari pada tahun ada sel F18 maka hasilnya 12.

Jika tahun pada sel B25 sama dengan tahun pada sel F18 maka hasilnya jumlah bulan pada sel F18.

Salin rumus excel di atas ke baris-baris berikutnya di kolom Jumlah bulan.

 

03. Kolom Penyusutan :

Masukkan rumus excel berikut ini :

=IF(OR($D$20=0;B25=” “);” “;IF($D$20=”Garis lurus”;SLN($C$16;$F$16;$F$14)/12*C25;IF($D$20=”Saldo menurun”;DB($C$16;$F$16;$F$14;COUNT($B$25:B25);C25))))

Keterangan rumus :

Jika sel D20 (metode penyusutan) bernilai nol atau sel B25 (baris #1 kolom tahun) bernilai kosong maka hasilnya kosong.

Jika sel D20 bernilai GARIS LURUS  maka hitung penyusutan aset dengan metode garis lurus.

Hasilnya dibagi 12 bulan kemudian dikali dengan jumlah bulan di sel C25 (baris #1 kolom jumlah bulan).

Jika sel D20 bernilai SALDO MENURUN, maka hitung penyusutan aset dengan metode saldo menurun.

Salin rumus excel di atas ke baris-baris berikutnya.

 

04. Kolom Akumulasi Penyusutan :

Masukkan rumus excel berikut ini :

=IF(OR($E$10=0;B25=” “);” “;SUM($D$25:D25))

Keterangan rumus :

Jika sel E10 (nama aset) bernilai nol atau B25 (baris #1 kolom Tahun) bernilai kosong maka hasilnya kosong. Jika tidak jumlahkan nilai pada sel D25 (baris #1 kolom penyusutan).

Salin rumus excel di atas ke baris-baris berikutnya.

 

05. Kolom Nilai Buku Aktiva :

Masukkan rumus excel berikut ini :

=IF(OR($E$10=0;B25=” “);” “;$C$16-E25)

Keterangan rumus :

Jika sel E10 (nama aset) bernilai nol atau B25 (baris #1 kolom Tahun) bernilai kosong maka hasilnya kosong.

Jika tidak maka kurangkan nilai sel C16 (harga perolehan) dengan nilai sel E25 (baris #1 kolom akumulasi penyusutan)

Salin rumus excel di atas ke baris-baris berikutnya.

Bila sampai langkah #4 ini benar,  maka hasilnya adalah  sebagai berikut :

Misalnya kita memilih Nama Aset : PERALATAN KANTOR dan Metode Penyusutan GARIS LURUS maka data-data lain akan ditampilkan sesuai dengan pilihan kita.

 

C: Sistem Aplikasi Penyusutan Aktiva Tetap

Setelah kita menyelesaikan semua langkah-langkah di atas, berikut ini penampakan lengkap dari sistem aplikasi penyusutan aktiva tetap dengan menggunakan Excel.

Sederhana, mudah dan aplikatif.

Selain itu ekonomis, namun cukup membantu pekerjaan dalam membuat laporan keuangan laba rugi dan Neraca (balanced sheet)

cara menghitung penyusutan
Aplikasi Excel untuk Menghitung Penyusutan Aktiva Tetap.

Demikian juga dengan pilihan-pilihan yang lain.

Akan sangat membantu kan, dan ndak perlu software mahal.

***

Dan untuk menambah wawasan dan pengetahuan kita, yuk saksikan video tutorial cara menghitung penyusutan metode saldo menurun berikut …

 

05: Kesimpulan

Demikian pembahasan tentang cara menghitung penyusutan menggunakan metode garis lurus dan saldo menurun dengan 2 fungsi Excel.

Dan dengan membuat sendiri sistem aplikasi penyusutan Excel. Mudah dan sederhana,

Mudah-mudahan apa yang sudah disampaikan bisa membantu Anda untuk menghitung nilai penyusutan aktiva tetap.

Seperti, peralatan kantor, kendaraan, komputer, dan aktiva tetap lainnya.

Bila anda masih kesulitan, silahkan konsultasikan ke kami.

Atau jika malas membuat sendiri, silahkan order yang sudah jadi dan SIAP PAKAI untuk BISNIS anda, tidak pakai lama dan tidak pakai ribet. asik kan?

Jangan lupa ordernya di sini ya > Accounting Tools & SOP Akuntansi Keuangan.

Buruan sebelum order closed.

Terima kasih *****

manajemen keuangan dan SOP