Sudahkah Anda menggunakan 2 Rumus Excel ini untuk Menghitung Nilai Penyusutan?

rumus excel untuk menghitung nilai penyusutan aktiva tetap

rumus excel untuk menghitung nilai penyusutan aktiva tetap

Microsoft Excel menyediakan rumus atau formula untuk menghitung nilai penyusutan aktiva.

Nilai penyusutan aktiva tetap harus diperhitungkan dengan akurat, karena akan mempengaruhi tingkat akurasi sebuah laporan keuangan baik Neraca maupun Laba Rugi.

Akuntansi penyusutan adalah suatu metode untuk mengalokasikan harga perolehan aktiva tetap ke periode-periode akuntansi.

Istilah penyusutan atau depresiasi digunakan untuk menunjukkan alokasi harga perolehan aktiva tetap berwujud yang dapat diganti seperti gedung, mesin dan peralatan.

Ada 3 faktor yang mempengaruhi besarnya beban depresiasi yang akan dialokasikan di tiap periodenya, yaitu :

#1. Harga perolehan (Aquisition Cost)

Adalah harga beli aset ditambah dengan biaya-biaya yang dikeluarkan sejak proses pembelian sampai dengan aset tersebut siap digunakan.

#2. Nilai Sisa (Salvage Value)

Adalah taksiran nilai uang yang akan diterima bila aset tersebut dijual setelah masa manfaatnya berakhir.

#3. Umur Ekonomis (Economical Life Time)

Adalah perkiraan jangka waktu pemakaian aset. Taksiran umur ekonomi ini bisa dinyatakan dalam periode waktu, jumlah hari produksi dan total jam kerja.

Baca juga : Inilah Cara Meningkatkan Akurasi Nilai Penyusutan Melalui Metode Penyusutan yang Tepat

Setelah ketiga faktor itu diketahui, maka selanjutnya adalah menghitung nilai penyusutan. Ada beberapa metode untuk menghitung nilai penyusutan.

Dan dalam kesempatan ini saya akan membahas 2 metode perhitungan nilai penyusutan, yaitu metode garis lurus (Straight Line Method) dan Metode Saldo Menurun (Declining Balanced Method).

Baca juga :

Yuk kita kaji satu per satu …

Metode Garis Lurus (Straight Line Method)

Dalam metode ini aset tetap memiliki kontribusi yang sama selama masa ekonomisnya, sehingga alokasi nilai penyusutannya pun sama dari waktu ke waktu.

Cara menghitungnya adalah :

(Harga Perolehan – Nilai Sisa) : Umur Ekonomis

Microsoft Excel menyediakan rumus yang dapat digunakan untuk menghitung nilai penyusutan aset dengan metode ini, yaitu rumus Excel SLN.

Penulisan rumusnya adalah sebagai berikut :

=SLN(cost;salvage;life)

Keterangan :
Cost       : Harga Perolehan Aset
Salvage : Nilai Sisa
Life        : Umur Ekonomis

Contoh :

PT Berkah Jaya membeli mesin penggorengan teri krispi senilai Rp. 100.000.000,-. Taksiran nilai sisa aset Rp. 10.000.000. Umur ekonomis 10 tahun.

Maka nilai penyusutan per tahunnya adalah :

=SLN(100000000;10000000;10)

= Rp. 9.000.000

Dan per bulannya adalah Rp. 9.000.000 : 12 = Rp. 750.000

 

Metode Saldo Menurun (Declining Balanced Method)

Metode ini beranggapan bahwa aset tetap akan memberikan kontribusi yang nilainya besar di awal periode pemakaian, selanjutnya akan terus menurun sampai akhir masa ekonomisnya.

Rumus Excel yang digunakan untuk menghitung nilai penyusutan dengan metode ini adalah DB (Declining Balance).




Penulisan rumusnya adalah sebagai berikut :

=DB(cost;salvage;life;periode;[month])

Keterangan :
Cost       : Harga Perolehan Aset Tetap
Salvage : Nilai Sisa
Life        : Umur Ekonomis
Periode : Penurunan tahun ke-
Month  : (optional) Jumlah bulan pertahun, bisa diabaikan dengan asumsi jumlah 12 bulan.

Contoh :

MyCom Computer Course membeli komputer untuk server senilai Rp. 25 juta.  Komputer itu akan dipakai selama 5 tahun. Nilai komputer setelah 5 tahun diperkirakan Rp. 500.000.

Berapa nilai penyusutan komputer tersebut tahun ke-4?

Nilai penyusutan komputer di tahun ke-4 adalah sebagai berikut :

=DB(25000000;500000;5;4)

= Rp. 1.295.652

Untuk membandingkan dua metode tersebut dan untuk mempermudah perhitungan nilai penyusutan sehingga bisa digunakan sebagai template maka bisa dibuat tabel seperti berikut ini:

Tabel Perhitungan aktiva tetap
Gambar. Tabel 1

Keterangan tabel :

Untuk mengetahui nilai penyusutan aset tetap tertentu, kita bisa memilih daftar nama aset dan metode penyusutan yang dikehendaki.

Selanjutnya kolom yang lain, yaitu tanggal perolehan, harga perolehan, awal periode penyusutan, taksiran masa manfaat, Taksiran Nilai Sisa, Akhir Periode Penyusutan,dan Nilai Penyusutan Aktiva secara otomatis data-data yang lain akan  ditampilkan.

Untuk membuat tabel perhitungan penyusutan Aktiva tetap seperti di atas langkah-langkahnya adalah sebagai berikut :

Langkah #1. Buat sheet dan berilah nama ASET TETAP. Tabel ini berisi daftar aset tetap yang dimiliki.

Bentuknya seperti ini :

Tabel Daftar Aset

Langkah #2. Buat sheet kedua dan berilah nama PENYUSUTAN. Bentuk tabelnya seperti gambar tabel 1 di atas.

Langkah #3. Masukkan rumus excel ke kolom-kolom berikut ini :

Nama Aset :

Buat list nama aset tetap dengan menggunakan fungsi Data Validation. Caranya klik Data – Data Validation. Maka akan muncul form dan isi seperti gambar berikut ini :

data validation

 

Kelompok Akun :

Masukkan rumus excel berikut ini :

=IF(ISBLANK(E10);” “;INDEX(‘Aset Tetap’!D10:D14;MATCH(E10;’Aset Tetap’!C10:C14;0)))

Keterangan rumus :

Jika sel Nama Akun bernilai kosong maka hasilnya kosong, jika tidak maka ambil data kelompok akun dari tabel aset tetap sesuai dengan nama aset yang dipilih di sel Nama Akun.

 

Tanggal Perolehan :

Untuk mengambil data tanggal perolehan aset dari tabel aset tetap, masukkan rumus excel berikut ini:

=IF(ISBLANK(E10);” “;INDEX(‘Aset Tetap’!E10:E14;MATCH(E10;’Aset Tetap’!C10:C14;0)))

 

Harga Perolehan :

Untuk mengambil data harga perolehan dari tabel aset tetap, masukan rumus excel seperti ini :

=IF(ISBLANK(E10);” “;INDEX(‘Aset Tetap’!F10:F14;MATCH(E10;’Aset Tetap’!C10:C14;0)))

 

Awal Periode Penyusutan :

Masukkan rumus excel seperti berikut ini :

=IF(ISBLANK(E10);” “;EOMONTH(C14;0))

Keterangan rumus :

Jika sel nama aset bernilai kosong maka hasilnya kosong, jika tidak maka fungsi EOMONTH akan menampilkan tanggal terakhirdari data bulan yang ada di sel Tanggal Perolehan.

 

Taksiran Masa Manfaat :

Untuk mengambil data taksiran masa manfa’at, masukkan rumus excel berikut ini :

=IF(ISBLANK(E10);” “;INDEX(‘Aset Tetap’!G10:G14;MATCH(E10;’Aset Tetap’!C10:C14;0)))

 

Taksiran Nilai Sisa:

Untuk mengambil data taksiran sisa, masukkan rumus excel berikut ini :

=IF(ISBLANK(E10);” “;INDEX(‘Aset Tetap’!H10:H14;MATCH(E10;’Aset Tetap’!C10:C14;0)))

 

Akhir Periode Penyusutan:

Masukkan rumus excel berikut ini :

=IF(ISBLANK(E10);” “;EDATE(C18;(F14*12)-1))

Keterangan rumus :

Jika sel Nama Akun bernilai kosong maka hasilnya kosong, jika tidak maka fungsi EDATE akan menampilkan data tanggal terakhir periode penyusutan yaitu tanggal awal periode ditambah jumlah periode penyusutan.

 

Metode Penyusutan:

Buat daftar metode penyusutan yang diinginkan dengan menggunakan fungsi Data Validation seperti langkah pertama.




Isikan data-data seperti dibawah ini :

data validation - metode penyusutan

Bila sampai tahapan ini dengan benar, maka ketika Anda memilih nama aset dan metode penyusutan tertentu maka data-data lain akan mengikutinya.

Contohnya Anda memilih nama aset MOTOR dan metode penyusutan GARIS LURUS, maka data-data lain akan mengikutinya.

aset tetap - motor

 

Langkah #4. Beralih ke tabel nilai penyusutan aktiva.

Kolom Tahun :

Baris #1. Masukkan rumus excel berikut ini :

=IF(ISBLANK($E$10);” “;YEAR(C18))

Keterangan rumus :

Jika sel Nama Aset bernilai kosong maka hasilnya kosong, jika tidak maka ambil data tahun dari sel Awal Periode Penyusutan.

Baris #2. Masukkan rumus excel beriku ini :

=IF(ISBLANK($E$10);” “;IF(B25<$B$25
+$F$14;B25+1;” “))

Keterangan rumus :

Jika sel nama aset bernilai kosong maka hasilnya kosong.

Jika nilai sel baris #1 kolom TAHUN lebih kecil dari hasil penjumlahan sel baris #1 ditambah sel di Taksiran Masa Manfaat, maka tambahkan nilai sel baris #1 dengan 1 (satu).

Selain itu hasilnya kosong.

Salin rumus Baris #2 di kolom Tahun sampai baris terakhir dari Tabel.

 

Kolom Jumlah Bulan :

Masukkan rumus excel berikut ini :

=IF(OR($E$10=0;B25=” “);” “;IF(B25=YEAR($C$18);12-MONTH($C$18)+1;IF(B25<YEAR($F$18);”12”;IF(B25=YEAR($F$18);MONTH($F$18)))))

Arti dari rumus excel di atas adalah Jika sel nama aset bernilai kosong maka hasilnya kosong.

Bila tahun pada sel B25 (baris#1 kolom Tahun) sama dengan tahun pada sel C18 (awal periode penyusutan) maka 12 dikurangi jumlah bulan pada sel C18 lalu ditambah 1.

Jika tahun pada sel B25 lebih kecil dari pada tahun ada sel F18 maka hasilnya 12.

Jika tahun pada sel B25 sama dengan tahun pada sel F18 maka hasilnya jumlah bulan pada sel F18.

Salin rumus excel di atas ke baris-baris berikutnya di kolom Jumlah bulan.

 

Kolom Penyusutan :

Masukkan rumus excel berikut ini :

=IF(OR($D$20=0;B25=” “);” “;IF($D$20=”Garis lurus”;SLN($C$16;$F$16;$F$14)/12*C25;
IF($D$20=”Saldo menurun”;
DB($C$16;$F$16;$F$14;COUNT($B$25:B25);C25))))

Keterangan rumus :

Jika sel D20 (metode penyusutan) bernilai nol atau sel B25 (baris #1 kolom tahun) bernilai kosong maka hasilnya kosong.

Jika sel D20 bernilai GARIS LURUS  maka hitung penyusutan aset dengan metode garis lurus, hasilnya dibagi 12 bulan kemudian dikali dengan jumlah bulan di sel C25 (baris #1 kolom jumlah bulan).

Jika sel D20 bernilai SALDO MENURUN, maka hitung penyusutan aset dengan metode saldo menurun.

Salin rumus excel di atas ke baris-baris berikutnya.

 

Kolom Akumulasi Penyusutan :

Masukkan rumus excel berikut ini :

=IF(OR($E$10=0;B25=” “);” “;SUM($D$25:D25))

Keterangan rumus :

Jika sel E10 (nama aset) bernilai nol atau B25 (baris #1 kolom Tahun) bernilai kosong maka hasilnya kosong. Jika tidak jumlahkan nilai pada sel D25 (baris #1 kolom penyusutan).

Salin rumus excel di atas ke baris-baris berikutnya.

 

Kolom Nilai Buku Aktiva :

Masukkan rumus excel berikut ini :

=IF(OR($E$10=0;B25=” “);” “;$C$16-E25)

Keterangan rumus :

Jika sel E10 (nama aset) bernilai nol atau B25 (baris #1 kolom Tahun) bernilai kosong maka hasilnya kosong.

Jika tidak maka kurangkan nilai sel C16 (harga perolehan) dengan nilai sel E25 (baris #1 kolom akumulasi penyusutan)

Salin rumus excel di atas ke baris-baris berikutnya.

Bila sampai langkah #4 ini benar,  maka hasilnya adalah  sebagai berikut :

Misalnya kita memilih Nama Aset : PERALATAN KANTOR dan Metode Penyusutan GARIS LURUS maka data-data lain akan ditampilkan sesuai dengan pilihan kita.

metode garis lurus
Demikian juga dengan pilihan-pilihan yang lain.

Akan sangat membantu kan?

Demikian pembahasan tentang perhitungan penyusutan dengan menggunakan aplikasi Excel.

Bila anda masih kesulitan, silahkan konsultasikan ke kami, atau order yang sudah jadi dan SIAP PAKAI untuk BISNIS anda, tidak pakai lama dan tidak pakai ribet. asik kan?

Jangan lupa ordernya di sini ya >>> Accounting Tools & SOP Akuntansi Keuangan.

Buruan sebelum order closed.

Terima kasih

***